当前位置导航:炫浪网>>网络学院>>网页制作>>ASP教程

使用ASP加密算法加密你的数据

简介
  
  首先简单介绍一下有关加密的背景。由于美国禁止几种密码算法的对外出口的加密位数(例如SSL的40位加密限制),本文将介绍一种ASP可以使用的简单字符加密算法,而不是那些受限制的加密算法。其实,这里介绍的加密算法对于一般的运用来说已经足够解密人麻烦一阵子的了。它的加密基础是最简单的Vernum密码方法,我将在下一篇文章中介绍这种密码。
  
  它的基本原理是,需要有一个需要加密的
  
  明文和一个随机生成的解密钥匙文件。然后使用这两个文件组合起来生成密文。
  (明文) 组合 (密钥) = 加密后的密文
  
  所以本文介绍的是生成密钥的代码。我们假设我们生成的密钥为512位长的密钥,它已经足够来加密一个文本字符了。代码如下:
  
  KeyGeN.asp文件
  <%
  '******************************
  ' KeyGeN.asp
  '******************************
  Const g_KeyLocation = "C:\key.txt"
  Const g_KeyLen = 512
  
  On Error Resume Next
  
  Call WriteKeyToFile(KeyGeN(g_KeyLen),g_KeyLocation)
  
  if Err <> 0 Then
  Response.Write "ERROR GENERATING KEY." & "<P>"
  Response.Write Err.Number & "<BR>"
  Response.Write Err.Description & "<BR>"
  Else
  Response.Write "KEY SUCCESSFULLY GENERATED."
  End If
  
  Sub WriteKeyToFile(MyKeyString,strFileName)
  Dim keyFile, fso
  set fso = Server.CreateObject("scripting.FileSystemObject")
  set keyFile = fso.CreateTextFile(strFileName, true)
  keyFile.WriteLine(MyKeyString)
  keyFile.Close
  End Sub
  
  Function KeyGeN(iKeyLength)
  Dim k, iCount, strMyKey
  lowerbound = 35
  upperbound = 96
  Randomize ' Initialize random-number generator.
  For I = 1 to iKeyLength
  s = 255
  k = Int(((upperbound - lowerbound) + 1) * Rnd + lowerbound)
  strMyKey = strMyKey & Chr(k) & ""
  next
  KeyGeN = strMyKey
  End Function
  
  %>
  
  在IIS下运行上面的KeyGeN.asp页面。你只需要如此做一次,他将把密钥写入文件c:\key.txt中 (如果你愿意的话,你也可以把这个文件放到另外一个更加安全的地方).然后你可以打开这个key.txt文件,它将包含512个ASCII码在35到96之间的字符.并且由于是随机生成的,所以每个人的私人密钥文件key.txt将是不一样的,下面是一个例子密钥文件:
  
  IY/;$>=3)?^-+7M32#Q]VOII.Q=OFMC`:P7_B;<R/8U)XFHC
  <SR_E$.DLG'=I+@5%*+OP:F_=';'NSY`-^S.`AA=BJ3M0.
  WF#T5LGK(=/<:+C2K/^7AI$;PU'OME2+T8ND?W$C(J\,;
  631'M-LD5F%%1TF_&K2A-D-54[2P,#'*JU%6`0RF3CMF0
  (#T07U'FZ=>#,+.AW_/+']DIB;2DTIA57TT&-)O'/*F'M>
  H.XH5W^0Y*=71+5*^`^PKJ(=E/X#7A:?,S>R&T;+B#<:-*
  \@)X9F`_`%QA3Z95.?_T#1,$2#FWW5PBH^*<])A(
  S0@AVD8C^Q0R^T1D?(1+,YE71X+.*+U$:3XO^Q].KG&0N0];
  [LJ<OZ6IN?7N4<GTL?(M'4S8+3JMK5]HC%^1^+K;$WBXPA?F&5^E\D$7%*O/U[1/?8(5:1OVWV*1Z-%`:K&V?X1,
  1KURD@3W0^D)<OG40?(VJ4EWL5A5M<$A);CQ36R9I]*U#Q%1
  <Y\&SA%#1<V
  
  下面再仔细分析一下上面的程序,我们发现其中的lowerbound和upperbound的数值其实就是你想使用来加密的ASCII字符范围。后面一篇文章中将介绍如何使用这个密钥来加密和解密一个字符串
  
  在第一部分,讨论了如何生成密钥,下面将介绍如何使用这个密钥来加密和解密一个字符串。
  
  下面的代码就是能够同时实现这个功能的函数
  
  Crypt.asp文件
  <%
  Dim g_Key
  Const g_CryptThis = "Now is the time for
  all good men to come to the aid of their country."
  Const g_KeyLocation = "c:\key.txt"
  
  g_Key = mid(ReadKeyFromFile(g_KeyLocation),1,Len(g_CryptThis))
  
  Response.Write "<p>ORIGINAL STRING: " & g_CryptThis & "<p>"
  Response.Write "<p>KEY value: " & g_Key & "<p>"
  Response.Write "<p>ENCRYPTED CYPHERTEXT: " & EnCrypt(g_CryptThis) & "<p>"
  Response.Write "<p>DECRYPTED CYPHERTEXT: " & DeCrypt(EnCrypt(g_CryptThis)) & "<p>"
  
  Function EnCrypt(strCryptThis)
  Dim strChar, iKeyChar, iStringChar, I
  for I = 1 to Len(strCryptThis)
  iKeyChar = Asc(mid(g_Key,I,1))
  iStringChar = Asc(mid(strCryptThis,I,1))
  ' *** uncomment below to encrypt with addition,
  ' iCryptChar = iStringChar + iKeyChar
  iCryptChar = iKeyChar Xor iStringChar
  strEncrypted = strEncrypted & Chr(iCryptChar)
  next
  EnCrypt = strEncrypted
  End Function
  
  Function DeCrypt(strEncrypted)
  Dim strChar, iKeyChar, iStringChar, I
  for I = 1 to Len(strEncrypted)
  iKeyChar = (Asc(mid(g_Key,I,1)))
  iStringChar = Asc(mid(strEncrypted,I,1))
  ' *** uncomment below to decrypt with subtraction
  ' iDeCryptChar = iStringChar - iKeyChar
  iDeCryptChar = iKeyChar Xor iStringChar
  strDecrypted = strDecrypted & Chr(iDeCryptChar)
  next
  DeCrypt = strDecrypted
  End Function
  
  Function ReadKeyFromFile(strFileName)
  Dim keyFile, fso, f
  set fso = Server.CreateObject("Scripting.FileSystemObject")
  set f = fso.GetFile(strFileName)
  set ts = f.OpenAsTextStream(1, -2)
  
  Do While not ts.AtEndOfStream
  keyFile = keyFile & ts.ReadLine
  Loop
  
  ReadKeyFromFile = keyFile
  End Function
  
  %>
  
  在Crypt.asp中我们首先从密钥文件中得到密钥值,然后从这段密钥中截取和我们需要加密的明文同样长度的密钥。然后使用一个简单的异或操作将明文和密钥进行运算,那么得到的结果就是加密后的密文了。过程很简单的。由于是使用了异或操作,所以解密将非常简单,只要使用同样的密钥对密文再次进行异或操作就能够解密了。在上面介绍的基础上,你可以少加改动,就可以使用同样的方法加密一个文件。唯一需要注意的是,对于一个二进制文件,你需要做一些完整性检查以保证转换回来的字符不要越界。现在你需要做的就是把密钥保存在服务器上的一个安全的地方(不能够被外部访问)
相关内容
赞助商链接